Skip to content

Resource: proxmox_network_applier

EXPERIMENTAL Reloads the network configuration of a single node, activating changes staged by interface resources that set reload = false (equivalent to PUT /nodes/{node}/network). The reload applies all staged changes on the node, not only those from resources this applier depends on.

The reload happens on create and on destroy. Changing any other attribute updates the resource in place without reloading; use triggers to force a new apply when something it depends on changes.

Example Usage

# Created first and destroyed last, so it applies the staged deletions on destroy.
# Nothing is staged when it is created, hence on_create = false.
resource "proxmox_network_applier" "finalizer" {
  node_name = "pve"
  on_create = false
}

# Staged only: nothing takes effect until the applier below reloads the node.
resource "proxmox_network_linux_bond" "bond0" {
  node_name = "pve"
  name      = "bond0"
  slaves    = ["eno1", "eno2"]
  bond_mode = "802.3ad"
  reload    = false

  depends_on = [proxmox_network_applier.finalizer]
}

resource "proxmox_network_linux_bridge" "vmbr0" {
  node_name = "pve"
  name      = "vmbr0"
  ports     = ["bond0"]
  address   = "10.0.1.10/24"
  reload    = false

  depends_on = [proxmox_network_applier.finalizer]
}

# Reloads on create, and again whenever an interface above changes.
# on_destroy = false because the finalizer applies the staged deletions.
resource "proxmox_network_applier" "apply" {
  node_name  = "pve"
  on_destroy = false

  lifecycle {
    replace_triggered_by = [
      proxmox_network_linux_bond.bond0,
      proxmox_network_linux_bridge.vmbr0,
    ]
  }

  depends_on = [
    proxmox_network_linux_bond.bond0,
    proxmox_network_linux_bridge.vmbr0,
  ]
}

Schema

Required

Optional

  • on_create (Boolean) Whether to reload on resource creation (defaults to true).
  • on_destroy (Boolean) Whether to reload on resource destruction (defaults to true).
  • timeout_reload (Number) Timeout for network reload operations in seconds (defaults to 100).
  • triggers (Map of String) Arbitrary values that force a new apply when they change.

Read-Only

  • id (String) Opaque identifier set to the Unix timestamp (milliseconds) when the apply was executed.